Initial MacTaskManager release

scripts/build-app.sh

@@ -0,0 +1,27 @@
+#!/bin/zsh
+set -euo pipefail
+
+PROJECT_DIR="${0:A:h:h}"
+APP_DIR="$PROJECT_DIR/dist/Task Manager.app"
+CONTENTS_DIR="$APP_DIR/Contents"
+ICON_SOURCE="$PROJECT_DIR/mactaskmanager.icon"
+
+cd "$PROJECT_DIR"
+swift build -c release
+
+mkdir -p "$CONTENTS_DIR/MacOS" "$CONTENTS_DIR/Resources"
+cp "$PROJECT_DIR/.build/release/MacTaskManager" "$CONTENTS_DIR/MacOS/MacTaskManager"
+cp "$PROJECT_DIR/Resources/Info.plist" "$CONTENTS_DIR/Info.plist"
+chmod +x "$CONTENTS_DIR/MacOS/MacTaskManager"
+
+if [[ -d "$ICON_SOURCE" ]]; then
+    xcrun actool "$ICON_SOURCE" \
+        --compile "$CONTENTS_DIR/Resources" \
+        --platform macosx \
+        --minimum-deployment-target 14.0 \
+        --app-icon mactaskmanager \
+        --output-partial-info-plist "$CONTENTS_DIR/Resources/IconInfo.plist" >/dev/null
+fi
+
+codesign --force --deep --sign - "$APP_DIR" >/dev/null
+print "Built $APP_DIR"

scripts/build-dmg.sh

@@ -0,0 +1,29 @@
+#!/bin/zsh
+set -euo pipefail
+
+PROJECT_DIR="${0:A:h:h}"
+APP_PATH="$PROJECT_DIR/dist/Task Manager.app"
+DMG_PATH="$PROJECT_DIR/dist/Task Manager-macOS.dmg"
+STAGING_DIR="$(mktemp -d /tmp/mactaskmanager-dmg.XXXXXX)"
+
+cleanup() {
+    rm -rf "$STAGING_DIR"
+}
+trap cleanup EXIT
+
+if [[ ! -d "$APP_PATH" ]]; then
+    "$PROJECT_DIR/scripts/build-app.sh"
+fi
+
+ditto "$APP_PATH" "$STAGING_DIR/Task Manager.app"
+ln -s /Applications "$STAGING_DIR/Applications"
+
+hdiutil create \
+    -volname "Task Manager" \
+    -srcfolder "$STAGING_DIR" \
+    -format UDZO \
+    -imagekey zlib-level=9 \
+    -ov \
+    "$DMG_PATH"
+
+print "Built $DMG_PATH"