// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/1/Mux4Way16.hdl
/**
 * 4-way 16-bit multiplexor:
 * out = a if sel = 00
 *       b if sel = 01
 *       c if sel = 10
 *       d if sel = 11
 */
CHIP Mux4Way16 {
    IN a[16], b[16], c[16], d[16], sel[2];
    OUT out[16];

    PARTS:
    // sel[0] pick from each group
    Mux16(a=a, b=b, sel=sel[0], out=lowGroup); // group ab
    Mux16(a=c, b=d, sel=sel[0], out=highGroup); // group cd
    // sel[1] pick which group
    Mux16(a=lowGroup, b=highGroup, sel=sel[1], out=out);
}
